tintin版本的新手护镖的机器人 --水平有限 -需要辅助手动

dashu

找了一圈也没找到，只能自己动手写。最近看还有几个新人也被新手镖郁闷着，发出来给新人参考吧。
抛砖引玉，求大佬讲讲全自动的怎么写。我看好几个小宝在全自动挂着，羡慕的我啊

dashu

参考了wiki上面的护镖任务的机器人说明写的。只支持福州镖局的新手镖。其他的不会。
把yourname 改成你的 name，然后在林震南那输入 gowork 即可。
被匪徒乱入以后需要手动定位回去，然后输入tuiche即可继续往下走了。
到了目的地以后，需要手动去找伙计，没写遍历，还有就是不会自己回去找林震南，这个也不会写，求高手指导。

#class biaoche open;

#nop 设置一些初始变量;
#var hubiao_flag 0;
#var go_num {0};
#var huoji {done};
#var address {done};
#var person {};
#var place {""};
#var yourname {菠萝};

#nop 设置赶车路径;
#ALIAS gc {gan che to %1};
#ALIAS ge {gan che to east};
#ALIAS genter {gan che to enter};
#ALIAS geu {gan che to eastup};
#ALIAS gn {gan che to north};
#ALIAS gne {gan che to northeast};
#ALIAS gnu {gan che to northup};
#ALIAS gnw {gan che to northwest};
#ALIAS gout {gan che to out};
#ALIAS gs {gan che to south};
#ALIAS gse {gan che to southeast};
#ALIAS gsu {gan che to southup};
#ALIAS gsw {gan che to southwest};
#ALIAS gw {gan che to west};
#ALIAS gwu {gan che to westup};
#ALIAS ged {gan che to eastdown};
#ALIAS gnd {gan che to northdown};
#ALIAS gwd {gan che to westdown};
#ALIAS gsd {gan che to southdown};
#ALIAS ww {wield sword;wield sword};
#ALIAS wb {unwield sword;unwield sword};
#ALIAS gd {gan che to down};
#ALIAS gu {gan che to up};

#alias {show_to_do} { #echo {{%1} {-1}}; };

#alias {gowork} {
        ask lin about job;
        #var target_num 0;
        listesc;
        #delay {3} {
                #if { $target_num > 0 } {
                        getesc $target_num;
                        getjobpath $target_name;
                        show_to_do {推镖目标：$target_name};
                };
        };
};

#action {^%d%s%S%s%d秒   待认领 0} {
         #var target_num  %1;
         #var target_name %3;
         say $target_num $target_name;
};


#alias {getjobpath} {
        #var go_num 1;
        #nop 往北出城;
        #list {jobpath} {create} {gs} {gs} {gw} {gn} {gn} {gn} {gnu} {gnw} {gnw};
        #list {pathroom} {create} {福威镖局} {东大街} {城中心} {北大街} {北门} {山路} {山路2} {山路3} {山路4};

        #if { "%1" == "苏州聚宝斋"} {
                #list {jobpath} {add} {gn} {gn} {gn} {gn} {gn} {gn} {gw};
                #list {pathroom} {add} {嘉兴南门} {嘉兴城} {青石官道} {南门} {南大街} {南大街2} {聚宝斋};
        };

        #if { "%1" == "嘉兴钱庄" } {
                #list {jobpath} {add} {gn} {gn} {ge} {gn};
                #list {pathroom} {add} {嘉兴南门} {嘉兴城} {嘉兴南湖} {嘉兴钱庄};
        };

        #if { "%1" == "嘉兴陆家庄大厅" } {
                #list {jobpath} {add} {gn} {gsw} {gsw} {gs} {genter} {genter} ;
                #list {pathroom} {add} {嘉兴南门} {乡间小径} {树林} {陆家庄} {天井} {大厅};
        };


        #if { "%1" =="牙山小荒地" } {
                #list {jobpath} {add} {gn} {gn} {ge} {gse} {gne} {ge} {gne} {gne} {ge} {ge} {ge} {ge} {ge} {ge} {ge} {gs} {gs} {gs};
                #list {pathroom} {add} {嘉兴南门} {嘉兴城} {嘉兴南湖} {嘉兴南湖2} {驿道} {驿道2} {驿道3} {驿道4} {西驿道} {西驿道2} {西驿道3} {牙山湾西口} {牙山湾西路} {牙山湾西路2} {牙山湾中心} {牙山湾南路} {牙山湾南路2} {小荒地};
        };

        #if { "%1" == "镇江飞龙镖局" } {
                #list {jobpath} {add} {gn} {gn} {gn} {gn} {gn} {gn} {gn} {gn} {gn} {gn} {gn} {gn} {gn} {gnw} {gn} {gne} {gne} {gn} {gnw} {gnw} {gw} {gw} {gw} {gw} {gn} {gn} {ge};
                #list {pathroom} {add} {嘉兴南门} {嘉兴城} {青石官道} {南门} {南大街} {南大街2} {宝带桥} {沧浪亭} {北大街} {北大街2} {北门} {青石官道} {青石官道2} {青石官道3} {青石官道4} {青石官
道5} {青石官道6} {青石官道7} {土路} {土路2} {青阳门} {东大街} {东大街2} {广场} {北大街} {北大街2} {飞龙镖局};
        };

        #if { "%1" == "泉州当铺" } {
                #list {jobpath} {add} {gs} {gs} {gs} {ge} {gn};
                #list {pathroom} {add} {武夷山路} {泉州北门} {城中心} {泉州港} {泉州当铺};
        };

        #if { "%1" == "岳王墓墓前广场" } {
                #list {jobpath} {add} {ge} {gn} {ge} {gne} {gn};
                #list {pathroom} {add} {小道} {小道2} {墓前小道} {墓前小道2} {墓前广场};
        };

        #if { "%1" == "临安府江南钱庄" } {
                #list {jobpath} {add} {gsw} {gw} {gsw} {gw} {gw} {gw} {gw} {gw} {gw} {gs} {genter} {gs};
                #list {pathroom} {add} {山路} {山路2} {山路3} {青石官道} {东青门} {东大街} {东大街2} {众安桥} {东大街3} {下瓦子} {下瓦子2} {江南钱庄};
        };

        #if { "%1" == "归云庄太湖街"} {
                #list {jobpath} {add} {gn} {gn} {gn} {gn} {gn} {gn} {gn} {gnw} {gw} {gw} {gw} {gw} {gw} {gw} {gnw} {gne} {gse} {gn} {gw} {gn} {ge};
                #list {pathroom} {add} {嘉兴南门} {嘉兴城} {青石官道} {南门} {南大街} {南大街2} {宝带桥} {西大街} {西大街2} {西门} {青石官道} {青石官道2} {青石官道3} {太湖湖边} {太湖湖边2} {草地
} {草地2} {草地3} {草地4} {草地5} {太湖街};
        };

        #if { "%1" == "南昌飞虎镖局" } {
                #list {jobpath} {add} {gs} {gnw} {gn} {gnw} {gn} {gn} {gn} {gn}{gn} {ge};
                #list {pathroom} {add} {武夷山路} {山路} {山路2} {山路3} {青石官道} {南昌南门} {南大街} {城中心} {北大街} {飞虎镖局}  ;
        };

        #list {jobpath} {add} {nod};
};



#act {^%S把这批红货送到%S那里，他已经派了个伙计名叫%S附近} {
        #var person %1;
        say %1 %2 %3;
        #if { "$person" == "$yourname" }  {
                #var address %2;
                #var huoji %3;
                #var go_num 1;
                set brief 2;
                #var target_name {$target_name $huoji};
                tuiche;
        };
} {4};


#alias {tuiche} {
        #ticker {tuichego} {
                #list {jobpath} {get} {$go_num} {gocmd};
                #list {pathroom} {get} {$go_num} {goroom};
                show_to_do {推镖目标：$target_name 下一步命令：$gocmd 下一步地点 $goroom };
                $gocmd;
        } {5};
        #class tuiche open;
        #action {你累了个半死，终于把镖运到了地头。} {#class tuiche kill;#untick {tuichego};say 镖送到了，回去吧！};
        #action {劫匪趁你不注意，推着镖车就跑，你赶紧追了上去。} {#class tuiche kill;#untick {tuichego};show_to_do {推镖目标：$target_name 下一步命令：$gocmd 下一步地点 $goroom  被打断}; } {4};
        #action {~你点了点头。} {#class tuiche kill;#untick {tuichego}; show_to_do {推镖目标：$target_name 到了，赶紧手工找人吧};};
        #action {~你赶着镖车} { #math {go_num} {$go_num+1}; };
        #class tuiche close;
};

#alias {tuiche.stop} {#class tuiche kill;#untick {tuichego};#echo 停止推车。;};

#action {你上一个动作还没有完成，不能施用内功。} {#delay {1} {yun recover;}} {4};
#action {劫匪突然从暗处跳了出来，阴笑道：“红货和人命都留下来吧！。”} {yun powerup;#delay {1} {hit robber;};} {4};
#action {忽然一阵刺骨的奇寒袭来，你中的星宿掌毒发作了！} {eat dan} {4};
#action {劫匪仓皇之际扔下了一些物品。} {#delay {1} {get all}} {4};
#action {劫匪怒道：嘴里不干不净地嘟囔什么！看招！} {hit robber;} {4};
#action {劫匪伸手一拦道：“想跑？没那么容易} {yun powerup;} {4};
#action {结果你被他一击命中，他的剧毒散至你的全身！} {eat yao;yun recover} {4};
#action {你还在战斗中！只能一次拿一样。} {#delay {1} {get all}} {4};
#action {{你气喘嘘嘘，看起来状况并不太好。|你已经陷入半昏迷状态，随时都可能摔倒晕|你似乎十分疲惫，看来需要好好休息了}} {yun recover;} {4};
#action {慢慢地你终于又有了知觉....} {#class tuiche kill;#untick {tuichego}; show_to_do { 推镖目标：$target_name 已经失败了，又被打晕了。赶紧回去吧。}; };


#class biaoche close;

wsstdh

厉害了。。

xuwenq

dashu 看短消息。

scivda

顶一个

xxhy

强