【华山派】新手任务攻略_为华山派继绝学附参考(已完结)

xsxxj · 发表于 2024-7-22 22:41:22

本帖最后由 xsxxj 于 2024-7-23 07:58 PM 编辑

华山派是金庸老先生作品中浓墨重彩的一笔，也是北侠中的老牌门派，独孤九剑更是引无数迷弟心生向往;

最近在群里也看到不少新人同学选择成为华山弟子，同样也有不少同学对新手任务比较苦手，为了追求进步，提前去做慕容，又被慕容按在地上摩擦，结果反而影响了成长速度;

看到几个和我一起进来的小伙伴甚至重新练了其他门派，师兄师弟又少了几个，着实痛心啊；

所以分享一下自己做新手任务的一些心得，希望能帮助让更多小伙伴顺利渡过新手阶段;

说得不对的地方还请各位大佬不吝赐教.

直达通道：

华山弟子新手备忘录

新人第一阶段目标

新手任务阶段岳灵珊巡山任务 (0-30k)

新手任务阶段宁中则指导任务(30-60k)

新手任务宁中则问好任务极少数本人只遇到1次(30-60k)

新手任务岳不群送信任务，接近主流任务，在这里不探讨;

后面楼层我会主要解读第1、2类任务以及我的机器人制作过程，完成这个前两类任务，经验足够支持技能达到80级去过阵了；

希望能够抛砖引玉，吸引大佬们出一些华山攻略;

另外，我用的客户端是Paotin++

同时支持windows，mac，安卓，ios

前期准备工作：

工具下载：

下载、安装教程（唯一同时支持Windows、IOS、安卓的通用客户端）

tools:paotin:install[北大侠客行MUD百科] (pkuxkx.net)

其他客户端的小伙伴，可以根据逻辑自行编写哈;

为了锻炼大家的动手能力，附件就不放了，内容全在帖子里

xsxxj · 发表于 2024-7-22 22:41:58

本帖最后由 xsxxj 于 2024-7-23 12:32 PM 编辑

华山弟子新手备忘录

1 学会使用node

所有场景名称后面带有五角星标志的地方，绝大多数情况下都可以使用node查询快捷行走的指令：

在扬州的中央广场输入：

node

复制代码

有3条路径可以去到华山

│ ★ yz_hssf │ 华山的书房 │ jumperless │ 18281 │

│ ★ yz_hslwc │ 华山的练武场 │ aqxmxp │ 18552 │

│ ★ yz_hs1 │ 华山的练武场 │ sister │ 6292 │

其中第二条

yz_hslwc

复制代码

可以直接到达华山拜师的地方，甚至travel都不用，及其方便；

到达练武场,s向南移动一步就是拜师地点（不拜师陆大有会拦路不给进，这一点直接造成了他天天被各大高手追砍

）：

男角色先拜陆大有；

女角色拜岳灵珊；

拜师指令：

bai lu;

复制代码

你想要拜陆大有为师。

陆大有说道：「好吧，小兄弟！我就收下你了！」

陆大有决定收你为弟子。

你跪了下来向陆大有恭恭敬敬地磕了四个响头，叫道：「师父！」

拜师之后在华山内是允许再去拜其他的师傅的，不会被认定为叛师；

同理在华山练武场node可以看到回扬州中央广场的路径

│ ★ hslwc_yz │ 扬州的中央广场 │ aqxmxp │ 14287

直接输入路径

hslwc_yz

复制代码

可以直达扬州的中央广场

2 学会使用lm \ lm 房间名查看当前所在位置以及目标位置

3 拜师后先到书房找到宁中则登记，之后间隔一段时间久可以来领钱了

2024-07-23 10:40:23 INPUT:

ask ning
about 生活费

复制代码

你向宁中则打听有关『生活费』的消息。

宁中则在一张帖子上写了点什么做记录。

宁中则说道：「好吧，以后每月你都来找我领生活费罢。」

xsxxj · 发表于 2024-7-22 22:44:13

本帖最后由 xsxxj 于 2024-7-23 12:32 PM 编辑

新人第一阶段目标：

做门派新手任务做到第二阶段，经验可以打到60k，支持技能等级80级;

如果按照我的机器人写法，任务穿插打坐，完成第二阶段任务，就具有一定内力基础了，这时候#send quit，退出游戏重新，会在扬州客栈重新登录，直接移动到中央广场

在扬州中心广场大榕树下pick guo，可以得到一颗果子，吃了涨1000经验，100潜能，40最大内力和最大精力，一辈子只能摘一颗吃。
在扬州中心广场，up上赏月台，ask lver about 月饼，会给你一枚月饼。answer 甜月饼，吃了涨50最大内力，answer咸月饼，吃了涨50最大精力。一辈子也只能吃一次。（推荐吃咸月饼，毕竟新手需要尽快增长精神）

看看根据下面的指引，把爱爱的装备领一下：

* 新手福利一览

最好设置快捷键，方便以后快速领取，比如:

#alias drw {
d;out;
draw sword;draw sword;draw armor;draw head;draw cloth;draw surcoat;draw boots;
enter;u;
wear all;
wield sword at right;
};

复制代码

站在扬州的中央广场,输入drw 就会把装备都领好，并且自动装备上

学基本内功和特内到80级。

因为过少林18罗汉阵要求除了知识类，学到身上的所有技能都要超过80级，所以潜能不够的话其它技能最好1级也别学，学了就要学到80；

*少林罗汉阵链接

打开后页面搜索关键字「十八罗汉阵」）

dazuo 内力达到接近最大内力上限，#send quit ，大退游戏重新进入，气血会刷新最大值（气血最大值与我们内力最大值直接正相关，内力最大值越大，气血上限越高）

了解剑心居，这可能是我们晚上角色最经常呆的地方，必须设置成#alias

#alias gojxj {
s;s;s;w;enter jianxinju;
};

复制代码

站在扬州的中央广场，输入gojxj 试一下

*剑心居

xsxxj · 发表于 2024-7-22 22:46:30

本帖最后由 xsxxj 于 2024-7-23 12:32 PM 编辑

岳灵珊巡山任务 part 1

任务解析

第一阶段（exp: 0-30k）

任务npc: 岳灵珊

位置：lm 客厅;

任务种类：华山巡弋

重点关注&Paotin中的应对方法：

1 触发，用于推动事情发展：等于系统给予指令-》帮助我们接受并分析指令，根据我们编写好的剧本内容去完成一系列事情,服务于我们。

2 不能过快移动:需要在指定的几个地点经历特定的事件后才能去到下一个地点，只是路过一次是无法完成任务的;

3 需要关注食物、饮水：这两项影响着气血、精神、精力的恢复，如果气血和精神到0会晕倒，从而导致任务失败;

4 巡弋干扰：镇岳宫地痞，看你长得好看会骚扰，导致busy，使得移动失败

5 有效利用闲暇时间：过快完成任务岳灵珊不收令牌，或者不给新任务，期间穿插原地打坐，进一步加速内力成长,美滋滋;

询问-》获取个人任务-》任务动作-》复命-》获得奖励-》继续下一个循环;而这个新手任务我们的目标是：只要手动做几遍任务，收集好触发，写成机器人，就可以让 paotin 自动帮我们搞定。

找到任务Npc可怜的岳灵珊妹子;

询问-》获取个人任务-》

ask yue lingshan about job;

机器人里一般用id全称，如果只用简称yue，别人的任务npc如果出现id中带有yue作为简称的，就会中断整个流程,所以推荐用全称(毕竟只需要我们输入一次就可以了);

你向岳灵珊打听有关『job』的消息。

岳灵珊对你说道：最近华山颇不安宁，你带着这块令牌去巡逻一下吧。

询问成功，Npc会贴心的给出一张地图，标志红色的就是需要我们巡弋的房间，这一点对新人来说真的太方便了;

给出了巡山路径：

n;n;e;sd;sd;sd;nu;nu;nu;w;nd;eu;wd;nu;wu;ed;nd;nd;nu;sd;wd;nd;wd;nd;nw;n;s;se;su;eu;su;eu;su;su;sd;su;s;s

也可以自己跑一趟录制一遍；

任务动作-》

依次按照路径移动到需要巡弋的房间

等待出现提示：你在练武场巡弋，尚未发现敌踪。

移动到下一个房间，在这个过程中需要记下来哪些房间是巡逻过的，巡逻过的房间不会再出现提示；

复命-》

give ling to yue lingshan;

你给岳灵珊一块令牌。

获得奖励-》继续下一个循环;

完成任务后，你被奖励了：

一百六十三点经验；

五十六点潜能；

一点江湖声望。

你已经通过华山派入门任务获得了一百六十三点经验，任务完成度为0.00%。

xsxxj · 发表于 2024-7-22 22:47:15

本帖最后由 xsxxj 于 2024-7-23 12:41 PM 编辑

岳灵珊巡山任务 part 2

剧本编写

对于这个流程，我们就可以编写剧本来做应对了：

第一部分：设计变量：

1.1帮助我们记录已经巡弋的房间信息

#var xunshan_done {};

复制代码

这里我用一个列表变量来记录;

1.2 帮助我们记录巡弋路径的变量:

#var xunshan_paths {n;n;e;sd;sd;sd;nu;nu;nu;w;nd;eu;wd;nu;wu;ed;nd;nd;nu;sd;wd;nd;wd;nd;nw;n;s;se;su;eu;su;eu;su;su;sd;su;s;s;};

复制代码

第二部分：设计触发，用于推动事情发展

2.1代表开启华山巡山功能;

#class
hs_xs open;

复制代码

2.2 代表收到服务器反馈接受任务成功时，启动寻路

#action {^岳灵珊对你说道：最近华山颇不安宁，你带着这块令牌去巡逻一下吧。} {
#delay 1 {okLog 1秒后开始巡逻.....};
#delay 2 {
path.WalkSteps {$xunshan_paths} {#delay 1 xs_submit};
};
};

复制代码

*特别关注 path.WalkSteps {$xunshan_paths} {#delay 1 xs_submit};《--- 这一句是核心，也是paotin的精髓之一:

他可以逐步把我们设定的路径走一遍，并且如果出现繁忙会自动重试；

完美的解决了我们前面提到的第四个需要重点关注的问题【巡弋干扰】busy导致行动失败：

并且提前设置了巡逻结束时候需要做的动作xs_submit（这是一个alias别名，后面会提到）;

#delay 1 代表着延迟1秒执行：

一是为了预防延迟问题导致出错，

二是作为玩家还是要也要替游戏着想啊，减少咱们重复发指令的频率，我发现这一点paotin做的很好。

感觉之后自己开发机器人时会高频使用;

2.3用于提交任务后延迟1秒执行qhs.on这个别名,并且为这个延迟起了一个名字叫做 xs_ask

这样就可以在后面不需要使用时，用#undelay随时取消这个延迟指令(感觉Paotin的作者是玩过mud的)

#action {^你给岳灵珊一块令牌。} {
#delay {xs_ask} {qhs.on} 1;
};

复制代码

2.4增加一个判断：

如果完成任务的速度过快，npc不接受复命，就打坐，提升内力，主打一个任务练功两不误。（这里我们是已经巡弋完所有地方的，只是因为Paotin帮我们做了大量判断工作，指示我们可以用最快的速度完成任务，所以不用担心）

#action {^这么快就回来了？肯定偷懒了吧？} {
dazuo 10;
#delay {xs_fm} {xs_submit} 5;
};
#action {^岳灵珊说道：「你刚刚做过任务，先去休息一会吧。」} {
dazuo 10;
#delay {xs_ask} {qhs.on} 5;
};

复制代码

2.5 在服务器判定已经完成本房间的巡弋时，仅延迟0.5秒就巡逻下一个房间，节省时间去练功；

#action {^你在%1巡弋，尚未发现敌踪。} {
#math xunshan_done[%1] {$xunshan_done[%1]+1};
#delay walk.Resume {path.Walk.Resume} 0.5;
};

复制代码

xsxxj · 发表于 2024-7-22 22:49:40

本帖最后由 xsxxj 于 2024-7-23 12:53 PM 编辑

岳灵珊巡山任务 part 3

解决难点“不能过快移动的问题”设计每一步巡弋要做的事情

画重点：这里定义了每一栋一步需要做什么事情；

3.1 先判断是否回到了巡弋的起点“客厅”，如果已经回到了客厅就认为路径巡逻结束了，会执行2.2 中提到的path.WalkStep 最后的那个回调参数xs_submit;

path.Walk.Stop; 是指每一步都暂停一下，执行一次等待;

path相关的内容都是Paotin自带的，无比强大。我们就不用单独去写一个行走模块了；

$gGMCP[Move][房间名]也是paotin自带的接口，直接就可以判断出我们当前在哪个房间；

解决了机器人不知道自己当前在哪的问题 , 小机啊，你也要自己学会变成一个聪明的机器人哦

；

在我们的巡逻路线中有两个后山小路，所以需要记录下来，只有后山小路巡逻了两次，才算通过；

其他的地方只要记录1次就完成了巡逻；

#alias {walk_time} {
#if {"$gGMCP[Move][房间名]" == "客厅"} {
      path.end;#return;
};
path.Walk.Stop;
#if {"$gGMCP[Move][房间名]" == "后山小路"} {
      #if {$xunshan_done[$gGMCP[Move][房间名]] == 2} {
         #delay walk.Resume {path.Walk.Resume} 0.2;
      };
};#elseif {@isTrue{$xunshan_done[$gGMCP[Move][房间名]]}} {
      #delay walk.Resume {path.Walk.Resume} 0.2;
};
};

复制代码

第四部分：解决问题3 - 需要关注食物、饮水

利用paotin自带的变量$char[HP]就可以轻松解决；每次接任务之前，我们问一下paotin，我饿不饿，我渴不渴，主打一个干饭人

;

#alias feed {
#if { $char[HP][食物] < 150 } {
#5 eat ganliang;
};
#if { $char[HP][饮水] < 150 } {
#5 drink tang;
};
};

复制代码

第五部分：设置任务开始时，我们要做什么，以及有事情需要处理时，怎么关闭机器;
5.1 开始工作 qhs.off(在岳灵珊的客厅输入就可以开始工作)

启动时初始化一次我们在第一部分设置的已巡游列表xunshan_done。表示我们现在要重新巡逻了；

并且用特有的$gMapRoom[name]询问一下paotin,我们是不是在客厅；

$gMapRoom 也是paoting 独有的，大大减少了我们的开发量，谁用谁知道，爱了爱了；

如果不在客厅就小小的报一下错；

在客厅的话，就使用event.Handle开始关注每一步移动，并对每一步移动做第三部分提到walk_time操作；（闭环了）；

完成准备工作后：ask yue lingshan about job; 领取任务

#alias qhs.on {
reload-module qhs;
feed;
#var xunshan_done {};
#if {"$gMapRoom[name]" != "客厅"} {
errLog "请在华山派-客厅岳灵珊的地方待命";
#return;
};
event.Handle {GMCP.Move} {path.Walk} {$MODULE} {walk_time};
ask yue lingshan about job;
};

复制代码

5.2 停止工作 qhs.off

停止工作时关闭移动时的观察；并且取消2个延迟询问

#alias qhs.off {
event.UnHandle {GMCP.Move} {path.Walk};
#undelay {xs_ask};
#undelay {xs_fm};
#class hs_xs kill;
};

复制代码

第六部分提交任务获取奖励：

6.1 提交任务

在前期做了大量铺垫的情况下(xs_submit在第二部分2.2中调用)，机器人会在完成了巡逻，到达客厅时直接把令牌交给岳灵珊

#alias xs_submit {
give ling to yue lingshan;
};

复制代码

6.2完成第一阶段任务后转第二阶段任务

#action {^岳灵珊说道：「你的功夫不错了，找我娘看看有什么任务交给你。」} {
reload-module nzz;
nzz.on;
qhs.off;
};

复制代码

第一类任务可以较好的解决了，后继更新继续更新，今天先这样啪，排版好累~ 。

xsxxj · 发表于 2024-7-22 22:59:51

本帖最后由 xsxxj 于 2024-7-23 12:14 PM 编辑

宁中则指导弟子任务 part 1

任务解析

第一阶段（exp: 30-60k）

任务npc: 宁中则

位置：lm 书房;

任务种类：找到并指导弟子

重点关注&Paotin中的应对方法：

难度略有提升比之前新增了三项

6 任务需要多次指点：而不像之前在一个地方做一个动作即可

7 判断是不是自己的小弟：避免找到的小弟不对

8 弟子开小差，需要漫山遍野的找到他：基本延续岳灵珊任务路线，多了个别房间

任务流程：

ask ning zhongze about job;

复制代码

你向宁中则打听有关『job』的消息。

宁中则对你说道：最近华山来了些新弟子，你带去练功房指点(zhidian)一下吧。

领取任务后会有一个小弟跟随你；

带着小弟移动到【练功房】指点

e;e;e;zhidian student

复制代码

指点出现下面提示，就代表小弟开小差去了，要去抓他回来；

趁你不注意，一溜烟不知道跑到哪里去了。

找到后，这里使用了Paotin友好的$user[id]，会把我们的id代入进去，避免追着别人的小弟指点，就非常的银杏;

ask $user[id]'s student about 指点;

复制代码

直到出现提示

xxx道：好吧，好吧，我回去还不行吗？

再次把他带回【练功房】指点;

zhidian student

复制代码

直至出现提示：

xxx一招一式有板有眼，你可以回去和宁中则复命了。

w;w;w;ask ning zhongze about finish;

复制代码

完成任务得到奖励;

xsxxj · 发表于 2024-7-22 23:00:29

本帖最后由 xsxxj 于 2024-7-23 12:50 PM 编辑

剧本编写

第一部分设计变量：

这里只有一个变量去找小弟的路径，简单多了吧

#var dizi_path{w;w;n;s;w;e;s;n;e;s;n;n;n;n;e;e;n;s;e;w;s;n;w;sd;sd;sd;nu;nu;nu;w;nd;eu;wd;nu;wu;ed;nd;nd;nu;sd;wd;nd;wd;nd;nw;ne;sw;w;e;n;s;se;su;eu;su;eu;su;su;sd;su;s;s;s;e};

第二部分：设计触发，用于推动事情发展

2.1 向宁女侠询问任务的时候开启，当成功领取了任务就调用 go_zhidian 这个别名去工作，并且关闭get_dizi，这个类别，避免干扰到其他触发；这里只是做一个Paotin进阶功能的演示，后面的任务会频繁用到，可能会出现多人挤在一起领任务，导致触发出错的情况，而养成及时关闭的好习惯，是大大降低错误触发的关键；

2.2 如果任务在cd阶段就原地打坐，表示抗议;

#action {^你向宁中则打听有关『job』的消息。} {
#class get_dizi open;
#action {^宁中则对你说道：最近华山来了些新弟子，你带去练功房指点(zhidian)一下吧。} {
      #delay 1 {
         go_zhidian;
         #class get_dizi kill;
      };
};
#action {^宁中则说道：「你刚刚做过任务，先去休息一会吧。」} {
      dazuo 10;
      #delay 5 { nzz.on };
};
#class get_dizi close;
};

复制代码

2.3 任务完成，就去提交任务，并领取新一轮任务

#action {%*一招一式有板有眼，你可以回去和宁中则复命了。} {
w;w;w;
#delay 1 {
ask ning zhongze about finish;
nzz.off;
};
#delay 2 {nzz.on};
};

复制代码

第三部分任务行动逻辑

3.1 在2.1的环节应用，移动到练功房，并指点小弟

#nop 移动到练功房并指导弟子;
#alias go_zhidian {
#delay 1 {e;e;e};
#delay 2 {zd_dizi};
};

复制代码

3.2 划重点：利用paotin的功能#tick 每2秒指点一次，解决第6个问题

3.3 利用paotin自带的$user[id]变量 解决问题7，使我们可以轻易辨识是不是我们的小弟；

3.4 增加一个触发，在小弟开小差的时候：关闭指导，并且用go_find_dizi这个别名(后面会解析)把他抓回来；

#alias zd_dizi {
#tick {tk_zhidian} {zhidian $user[id]'s student} {2};
#class zhidian_start open;
#action {%*趁你不注意，一溜烟不知道跑到哪里去了。} {
#untick {tk_zhidian};
#delay 2 go_find_dizi;
};
#class zhidian_start close;
};

复制代码

3.5 揪住小弟不放手

paotin巨大重要的灵魂功能: map.FocusNPC

可以帮助我们在遇到某个名字、ID的npc时做某事，再也不用眼睛盯着了，保护视力（先做几下眼保健操）

map.FocusNPC {{id} {$user[id]'s student}}command {get_dz};

这里是在发现包含本人id的弟子时，执行get_dz别名的功能，简单好用，至少为我们剩下100行代码的工作量；

event.Handle、path.WalkSteps在前面有提到，这里不再赘述，有疑问可以回帖交流；

#nop 触发去寻找指导的弟子;
#alias go_find_dizi {
map.FocusNPC {{id} {$user[id]'s student}} command {get_dz};
event.Handle {GMCP.Move} {path.Walk} {$MODULE} {zd_walk_time};
path.WalkSteps {$dizi_path} {#delay 1 zd_dizi};
};

复制代码

3.6 这里代表找到了弟子，让弟子跟随，并用map.FocusNPC取消对这个弟子的关注，感谢大佬的指点；

#nop 让弟子继续跟随你;
#alias get_dz {
#undelay walk.Resume;
#action {%*道：好吧，好吧，我回去还不行吗？} {
      #delay walk.Resume {path.Walk.Resume} 0.1;
      map.FocusNPC;
      #untick {tk_ask_dizi};
};
#tick {tk_ask_dizi} {ask $user[id]'s student about 指点;} {2};
};

复制代码

3.7 这里是设置每一步需要做的事情，如果是到到了终点【练功房】。就关闭走路，并执行回调的代码#delay 1 zd_dizi ;

#alias {zd_walk_time} {
#if {"$gGMCP[Move][房间名]" == "练功房"} {
path.end;#return;
};
path.Walk.Stop;
#delay walk.Resume {path.Walk.Resume} 0.2;
};

复制代码

3.8 任务的开启和关闭，与第二阶段几乎相同，在任务前先吃喝（吃货本色）;

#alias nzz.on {
reload-module qhs;
feed;
#var xunshan_done {};
#var step_count 0;
#if {"$gMapRoom[name]" != "书房"} {
errLog "请在华山派 -> 书房宁中则女侠身边再开启nzz.on";
#return;
};
ask ning zhongze about job;
};

复制代码

#alias nzz.off {
path.Walk.Stop;
#undelay walk.Resume;
event.UnHandle {GMCP.Move} {path.Walk};
};

复制代码

xsxxj · 发表于 2024-7-22 23:18:10

本帖最后由 xsxxj 于 2024-7-23 12:29 PM 编辑

来自宁女侠的问好任务

这个任务要求你向3~5名指定的在线玩家之一问好（wenhao）

注意是真实的玩家，很多玩家跑的飞快，所以我们需要定位不怎么移动的玩家，再过去找；

你向宁中则打听有关『job』的消息。

宁中则看着你，道：好久没有见过脚鱼客(footfisher) 伊凡(efan) 逍遥龙鹤(sunlife) 这些人了，你在江湖中，如果遇到这些前辈

中的一个，代我向他问个好(wenhao)吧，并把礼品带给他。

任务完成后直接在宁中则面前输入finish，如果无法完成，请输入fail。

此时需要打开helpme聊天频道

tune channel helpme

使用helpme find 命令查看这些玩家在哪里

helpme find xxx <-这里是括号里的英文id，不是中文名字

等待npc悄悄告诉你，xxx现在正在xxx，快去摁死他吧。
这里，我们最好把提供的3个玩家id，都问上两遍，从里面挑选，期间没有移动过的，再去找到这位仁慈的玩家；

注意，只需要找到其中的1位就好；

去到对应地方，在该玩家面前输入

wenhao xxx <-这里是括号里的英文id，不是中文名字

2024-07-22 20:45:45 INPUT: wenhao efan

你对着伊凡深深一揖：鄙派掌门向伊凡问好。

闲聊会有提示：

【闲聊】伊凡(Efan): 伊凡在此，请云与月小兄弟也代为向岳掌门、宁女侠问好。

随后返回华山，在宁中则面前输入

finish <-注意是直接finish，

2024-07-22 20:49:41 INPUT: finish

完成任务后，你被奖励了：

一千零三十四点经验；

八百二十二点潜能；

二百一十三点江湖声望。

二点内力。

你已经通过华山派入门任务获得了三万四千四百八十二点经验，任务完成度为33.45%。

不是askning about finish x

你向宁中则打听有关『job』的消息。

宁中则说道：「你上次任务还没有完成呢！」

任务完成，可以继续找宁中则要指点弟子任务了。

另：如实在找不到对应玩家等情况需要放弃任务，找宁中则输入：

ask ning about fail

放弃任务无惩罚，但再次接取仍然是问好任务，只是对象有变，所以无法通过放弃跳过问好任务。

参考 wiki《华山派》

xsxxj · 发表于 2024-7-23 12:36:35

完结，撒花

感谢paotin群和萌新群里各位大佬的帮助 bow

		自动登录	找回密码
密码			注册